// Edit enumerated object link attributes

/*
  Edit enumerated object link attributes
  - cannot edit multivalue attributes

  Pekka Mäkinen / SoftQA Oy
  2013-07-09
  Copyright (c) 2013 SoftQA Oy

  Creative Commons license: Attribution 3.0 Unported (CC BY 3.0)
  http://creativecommons.org/licenses/by/3.0/

*/


//////////////////////////////////////////////
//  Pragmas
pragma runLim,0


//////////////////////////////////////////////
//  Constants

// Version number for the script
const string scriptVersion = "1.00"

// Maximum number of modules for the name arrays
const int MAX_MODULES = 200

// Maximum number of attributes for the name arrays
const int MAX_ATTR = 50


//////////////////////////////////////////////
//  Variables

// Modules
Module LinkMod = null
string srcMod = ""
string trgMod = ""
Module currMod = null

// Object variables
Object o = null
Object currObj = null

// Integer for storing Absolute Number
int absNo = 0

// Link variables
Link l = null
Link currLink = null

// ModuleNames is used to store linked modules to selected module
int NumModules = 0
string ModuleNames[MAX_MODULES]

// AttrNames is used to store link attributes and their values
int NumAttr = 0
string AttrNames[MAX_ATTR]

// A skip list for link information
Skip LinkList = null

// A skip list for link attribute information
Skip AttrList = null


//////////////////////////////////////////////
//  Dialog boxes
DB  MainDB = null
DBE ModuleListDBE = null
DBE editBtn = null
DBE cancelBtn = null
DBE nextBtn = null
DBE previousBtn = null
DBE MainDBLabel = null
DBE EditListDBE = null


///////////////////////////////////////////////////////////
//  Subroutines
/*******************************************************************************
* doCancelDB
* Cancel
*/
void doCancelDB(DB mBox)

{
  hide mBox
  destroy (mBox)
  mBox = null

  Module m = null

  // Close open modules
  for m in database do
    {
	 if (isRead(m) && (m != currMod))
	    {
		 close(m)
	    }
    }
}

/*******************************************************************************
* doCancelMain
* Cancel
*/
void doCancelMain(DBE mBox)

{
  hide MainDB
  destroy (MainDB)
  MainDB = null

  Module m = null

  // Close open modules
  for m in database do
    {
	 if (isEdit(m) && (m != currMod))
	    {
		 save (m)
		 close(m)
	    }
    }

  if (!null LinkList)
    {
     delete LinkList
     LinkList = null
    }
  if (!null AttrList)
    {
     delete AttrList
     AttrList = null
    }
}

/*******************************************************************************
 * RefreshListDBE
 * Update linked module names to an array
 */
void RefreshListDBE(Object o, bool Refresh)

{
    int i = 0
    string SrcModName = ""
    ModName_ SrcModRef = null
    Module TempModule = null

    if (Refresh)
      {
	   empty(ModuleListDBE)
      }

    // Clear the array of all previous information
    for (i=0;i<MAX_MODULES;i++)
       {
	    ModuleNames[i] = ""
       }

    NumModules = 0

    // Delete and re-create the skip list
    delete LinkList
    LinkList = null
    LinkList = create

	for l in o -> "*" do
	   {
	    LinkMod = module l
	    trgMod = target l
	    absNo = targetAbsNo l
	    ModuleNames[NumModules] = name(LinkMod) " -> " trgMod " -> " absNo""
	    if (Refresh)
	       {
	        insert(ModuleListDBE, NumModules, ModuleNames[NumModules])
                }
	    put(LinkList, NumModules, l)
	    NumModules++
	   }

	for SrcModRef in o <- "*" do
	   {
		SrcModName = fullName SrcModRef
		if ((!null SrcModRef ) && (!open module SrcModName))
		   {
			TempModule = edit(SrcModName, false)
			if (null TempModule)
			   {
				ack "Module " name(SrcModRef) " can not be edited - can not edit link attributes"
			   }
		   }
	   }

	for l in o <- "*" do
	   {
	    LinkMod = module l
	    srcMod = source l
	    absNo = sourceAbsNo l
	    ModuleNames[NumModules] = name(LinkMod) " <- " srcMod " <- " absNo""
	    if (Refresh)
	       {
	        insert(ModuleListDBE, NumModules, ModuleNames[NumModules])
               }
	    put(LinkList, NumModules, l)
	    NumModules++
	   }
}


/*******************************************************************************
* RefreshLinkAttr
* List again enumerated link attributes (not multi-valued) for the defined link
*/
void RefreshLinkAttr (Link l, bool Refresh)

{
    int i = 0
    AttrDef ad = null
    AttrType at = null
    string tempString = ""

    if (Refresh)
	   {
	    empty(EditListDBE)
	   }

    // Clear the array of all previous information
    for (i=0;i<MAX_ATTR;i++)
       {
	    AttrNames[i] = ""
       }

    NumAttr = 0

    // Delete and re-create the skip list
    delete AttrList
    AttrList = null
    AttrList = create

    if (null l) return

    LinkMod = module l

    for ad in LinkMod do
	   {
		at = ad.type
                tempString = ad.name ""
		if ((!null at) && (ad.object) && (stringOf(at.type) == "Enumeration") && (!ad.multi) && (canModify(LinkMod, tempString)))
                   {
			// Add attribute name and value to list
			AttrNames[NumAttr] = tempString ": " l.tempString ""
			put(AttrList, NumAttr, ad)
			if (Refresh)
			  {
			   insert(EditListDBE, NumAttr, AttrNames[NumAttr])
			   }
			NumAttr++
	          }
       }
}


/*******************************************************************************
* moveNext
* Move to next object and update
*/
void moveNext (DBE dbe)

{
  Object nextObj = next currObj
  current = currMod
  if (!null nextObj)
    {
	 current = nextObj
	 currObj = nextObj
	 refresh currMod
	 RefreshListDBE(nextObj, true)
	 currLink = null
	 RefreshLinkAttr (currLink, true)
	 set(MainDBLabel, "Object ID " currMod."Prefix" nextObj."Absolute Number" "")
    }
}

/*******************************************************************************
* movePrevious
* Move to previous object and update
*/
void movePrevious (DBE dbe)

{
  Object prevObj = previous currObj
  current = currMod
  if (!null prevObj)
    {
	 current = prevObj
	 currObj = prevObj
	 refresh currMod
	 RefreshListDBE(prevObj, true)
	 currLink = null
	 RefreshLinkAttr (currLink, true)
	 set(MainDBLabel, "Object ID " currMod."Prefix" prevObj."Absolute Number" "")
    }
}


/*******************************************************************************
* toggleValueNull
* Callback for change value of a link attribute (single click)
*/
void toggleValueNull (DBE dbe)

{
  // Do nothing
}


/*******************************************************************************
* toggleValue
* Callback for change value of a link attribute (double click)
*/
void toggleValue (DBE dbe)

{
    int i = 0
    AttrDef ad = null
    AttrType at = null

    string tempString = ""
    string CurrentValue = ""
    int SelectedAttr = get(EditListDBE)
    int EnumValues = 0

    // If nothing selected, then return
    if (SelectedAttr < 0) return

   if (!find(AttrList, SelectedAttr, ad))
     {
	  // The selected link was not found in list
	  ack "The selected attribute was not found in list"
	  return
     }
   else
     {
	  tempString = ad.name""
	  at = ad.type
	  CurrentValue = currLink.tempString ""
	  if (canWrite(currLink.tempString))
	     {
		   EnumValues = at.size
		   for (i = 0; i < EnumValues; i++)
		      {
			   if (at.strings[i] == CurrentValue)
			      {
				   break
			      }
		      }
		   if (i < (EnumValues-1))
		     {
	               currLink.tempString = at.strings[i+1]
                     }
           else
             {
	          currLink.tempString = at.strings[0]
             }
	      RefreshLinkAttr (currLink, true)
	      set(EditListDBE, SelectedAttr, true)
	     }
	  else
	     {
		   ack "Can not modify link attribute " tempString ""
	     }
     }
}


/*******************************************************************************
* editAttr
* Callback for attribute editor
*/
void editAttr (DBE dbe)

{
  int SelectedLink = get(ModuleListDBE)

  // If nothing selected, then return
  if (SelectedLink < 0) return

  if (!find(LinkList, SelectedLink, currLink))
     {
	  // The selected link was not found in list
	  ack "The selected link was not found in list"
	  return
     }

  if (!null currLink)
     {
      RefreshLinkAttr(currLink,true)
     }
  else
     {
	  // The selected link was not found in list
	  ack "The selected link was not found in list"
	  return
     }

  // Select the first one
  set(EditListDBE, 0, true)

}

//////////////////////////////////////////////
//  Main program

if (null current Module)
 {
  ack "Please run this script from a module"
  halt
 }
else
 {
   currMod = current
 }

currObj = current

MainDB = create ("Edit enumerated link attributes " scriptVersion "", styleCentered|styleFloating)

// Create the link list
RefreshListDBE(currObj, false)

ModuleListDBE = list(MainDB, "  Links on this object", 400, 10, ModuleNames, NumModules)

// Build up the buttons
below MainDB
// We will supply own Cancel button
close (MainDB, false, doCancelDB)
cancelBtn = button(MainDB, "Close", doCancelMain, true)
beside MainDB
previousBtn = button(MainDB, "Previous object", movePrevious, true)
beside MainDB
nextBtn = button(MainDB, "Next object", moveNext, true)
beside MainDB
MainDBLabel = label(MainDB, "   Object ID " currMod."Prefix" currObj."Absolute Number" "")

below MainDB
label(MainDB,"")

below MainDB
// Link attribute edit window
EditListDBE = list(MainDB, "  Enumerated attribute values on selected link", 400, 10, AttrNames, NumAttr)

below MainDB
label(MainDB,"")

// Realize window
realize MainDB

// Refresh the link list
RefreshListDBE(currObj, true)

// Set selection callback for ModuleListDBE
set(ModuleListDBE, editAttr, editAttr)

// Set selection callback for EditListDBE
set(EditListDBE, toggleValueNull, toggleValue)

// Show the window
show MainDB